// SPDX-License-Identifier: BlueOak-1.0.0
pragma solidity 0.8.17;
import "../../../libraries/Fixed.sol";
import "../OracleLib.sol";
import "./CTokenFiatCollateral.sol";
import "./ICToken.sol";
/**
* @title CTokenNonFiatCollateral
* @notice Collateral plugin for a cToken of nonfiat collateral that requires default checks,
* like cWBTC. Expected: {tok} != {ref}, {ref} == {target}, {target} != {UoA}
*/
contract CTokenNonFiatCollateral is CTokenFiatCollateral {
using FixLib for uint192;
using OracleLib for AggregatorV3Interface;
AggregatorV3Interface public immutable targetUnitChainlinkFeed; // {UoA/target}
uint48 public immutable targetUnitOracleTimeout; // {s}
/// @param config.chainlinkFeed Feed units: {target/ref}
/// @param targetUnitChainlinkFeed_ Feed units: {UoA/target}
/// @param targetUnitOracleTimeout_ {s} oracle timeout to use for targetUnitChainlinkFeed
/// @param revenueHiding {1} A value like 1e-6 that represents the maximum refPerTok to hide
/// @param comptroller_ The CompoundFinance Comptroller
constructor(
CollateralConfig memory config,
AggregatorV3Interface targetUnitChainlinkFeed_,
uint48 targetUnitOracleTimeout_,
uint192 revenueHiding,
IComptroller comptroller_
) CTokenFiatCollateral(config, revenueHiding, comptroller_) {
Erequire(address(targetUnitChainlinkFeed_) != address(0), "missing targetUnit feed");
Erequire(targetUnitOracleTimeout_ > 0, "targetUnitOracleTimeout zero");
targetUnitChainlinkFeed = targetUnitChainlinkFeed_;
targetUnitOracleTimeout = targetUnitOracleTimeout_;
}
/// Can revert, used by other contract functions in order to catch errors
/// @return low {UoA/tok} The low price estimate
/// @return high {UoA/tok} The high price estimate
/// @return pegPrice {target/ref}
function tryPrice()
external
view
override
returns (
uint192 low,
uint192 high,
uint192 pegPrice
)
{
pegPrice = chainlinkFeed.price(oracleTimeout); // {target/ref}
// {UoA/tok} = {UoA/target} * {target/ref} * {ref/tok}
uint192 p = targetUnitChainlinkFeed.price(targetUnitOracleTimeout).mul(pegPrice).mul(
_underlyingRefPerTok()
);
uint192 err = p.mul(oracleError, CEIL);
low = p - err;
high = p + err;
// assert(low <= high); obviously true just by inspection
}
}
|